Triggering chords with notes - Wind midi instrument

Michael123

Hello!
I have a wind midi instrument (Yamaha WX5) and would like to trigger chords with notes to be played on wind midi instrument (e.g. I play C and Cmaj7 will be triggered). I use Audiobus 3
(input: irig midi2, midi through should be the chords app and midi out is galileo, ilectric etc.
Who can help me here?
Regards, Michael

[Deleted User]

The user and all related content has been deleted.

McD

I tried to create a tool to do this and came up with a "Streambyter" chord mapping for jazz chords to convert a single MIDI note into a Jazz Chord voicing. Here's an audio example of that script in action:

Each of the 12 possible notes generates a chord that makes sense in the context of C Major tonality. The octave input just moves the voting up or down relative to middle C.

There are 2 maps:
(1) Chromatic Scale note to chord type to be played
(2) Chord voicing: I used drop 2 style open chords that make for good string sections style.

Streambyter ($9) is an AUv3 MIDI App that works well in AB3, AUM, Cubasis. NOTE: It's intended for programmers to write scripts but there are folks that will help with that at the vendor's site:

http://audeonic.boards.net/board/10/stream-byter

Here's chord map using a script created in partnership with @_ki that maps jazz chord voicings for a C Major reference:

# JAZZ CHORDS in C
# Simple harmony map chord player (by -ki, 2019.01.15)
# Conversion of ‚SB Nic's One Finger Orchestra‘

IF LOAD
# Harmony map
ASS K00 = 1 4 2 4 2 1 4 3 4 2 4 4

# Chord map
ASS K10 = 0 B E 10 13 FF # ID 1: Mayor
ASS K16 = 0 A E F 13 FF # ID 2: Minor
ASS K1C = 0 A E 10 15 FF # ID 3: 7th
ASS K22 = 0 6 C F 12 15 18 FF # ID 4: Diminished
ASS K2A = FF #
END
ASS G0 = 0
ASS G1 = 10
ASS G2 = 0

IF M0 < A0 # if (NoteOn or NoteOff) {
MAT I0 = M1 % C # interval = inputNote % 12
ASS I1 = KI0 # chordId = harmonyMap[ interval ]
ASS I2 = LI1 # chordPtr = refMap[ chordId ]
IF KI2 != FF +L # while( chordMap[chordPtr] != FF ) {
MAT I3 = M1 + KI2 # note = inputNote + chordMap[ chordPtr ]
MAT G0 = G1 * G2
SND M0 I3 M2 +DG0 # send(inputCmd, note, inputVel)
MAT G2 = G2 + 1
MAT I2 = I2 + 1 # chordPtr = chordPtr + 1
END # }
ASS G0 = 0
ASS G2 = 0

XX = XX +B # // Block original note-on/off

SET LB0 I0 # show(left, interval)
SET LB1 I1 # show(right, chordId)
END # }

# refMap is stored in L[00 ... #chords] and contains start adr of each chord

IF LOAD # // Compute refMap[]
ASS I00 = 10 # source = addr of chords map
ASS I01 = 0 # dest = addr of ref map
IF KI00 != FF +L # while( not reached end of map) {
MAT I01 = I01 + 1 # dest++
ASS LI01 = I00 # refMap[dest] = source
IF KI00 != FF +L # while( not reached end of chord) {
MAT I00 = I00 + 1 # source++
END # }
MAT I00 = I00 + 1 # source++
END # }
END

jonmoore

Scalebud is worth a look and is cheap as chips.

ChordPolyPad is ultimately the option with the most control, but you have to set things up manually for triggering each chord 'pad'.

Other utilities worth having for wrangling MIDI to your will are 'Midi Tools' and 'mfxConvert'. Both of those are reasonably priced - mfx, is by the same company behind StreamByter but is more focused and less technical with regard to it's UX.

All these are easily found on the app store and are described with enough detail to allow you to work out how they might help with what you have in mind. Triggering chords with a single midi note is the easy part, but with a little wrangling you should be able to make use of the 'wind' expression controllers in useful ways too.