IPhone App to map upward/downward velocity values spread across a keyboard?

wholefoods666

Hey y'all, haven't had much luck doing a search on this topic - I want to make lower notes louder and the higher notes softer when playing a midi keyboard. Something that can map velocity values from the keys C1-C5 as slowly decreasing from 127 to 70 for example. Also, has to be an IPhone app, thanks!

blipson

I had to get a Bome Box to do that--saved my life.

On iPad, Midiflow says it does velocity remapping. I bought it, but I haven't tested it out yet. Post here if it works for you.

Korakios

You need keytrack to velocity modifier . Maybe a Mozaic or Streambyter preset would help.
I’m sure someone will offer to write a patch , but if not I could write in PureData and load it in PdParty (not AU) app .

rs2000

That's one of the few useful things that Victor Porof's MIDI Tools can do:

Edit: Sorry, I should have read your question patiently 😅
His "MIDI Key Zone" plugin does something like that but it's iPad only.

MidiFlow is good, it runs on iPhone and it's a good compromise between complexity and features. You will need the Controller Remapping IAP.
For AUv3 use I'd pick StreamByter.

dendy

.

wholefoods666

Appreciate all the replies - I purchased Midiflow and I see note remapping and velocity remapping options by themselves, but how would you remap velocities based on note values?

blipson

@wholefoods666 said:
Appreciate all the replies - I purchased Midiflow and I see note remapping and velocity remapping options by themselves, but how would you remap velocities based on note values?

I don't know--I was hoping you'd report on everything and save me time when I get to Midifow!

Seriously, I'm working out issues with my hardware Bome Box and need to work on some configs to interface it with my iPad. It could be weeks until I get to Midiflow, but an all-iPad configuration might be nice. So I'm following this thread.

wim

I don't know if you have Mozaic or not, but if you do, then this script should work. (No pressure or obligation to buy Mozaic or use the script. I just wrote it for fun.)

@Description
Scale Velocity by Note

Set "V0" to the velocity you want the lowest note (note 0) to play.Set "v127" to the velocity note 127 should play. Velocity will be scaled linearly between the two velocities across the note range.

Script idea by Audiobus forum member @wholefoods666
@End


@OnLoad
  if Unassigned init
    init = YES
    v_note0 = 127
    v_note127 = 70
    SetKnobValue 0,v_note0
    SetKnobValue 1,v_note127
    Call @KnobLabels
  endif

  LabelKnobs { }
  ShowLayout 4
@End

@OnMidiInput
  if MIDICommand <> 0x90
    SendMIDIThru 
  endif
@End

@OnMidiNoteOn
  if v_note0 > v_note127
    n = 127 - MIDINote
  else
    n = MIDINote
  endif
  velocity = TranslateScale n,0, 127, v_note127,v_note0
  SendMIDINoteOn MIDIChannel,MIDINote,velocity
@End

@OnSysex
  SendSysexThru
@End

@OnKnobChange
  knob = LastKnob
  value = GetKnobValue knob 

  if knob = 0
    v_note0 = Round value
    elseif knob = 1
    v_note127 = Round value
  endif

  call @KnobLabels
@End

@KnobLabels
  LabelKnob 0,{v0: }, v_note0
  LabelKnob 1,{v127: }, v_note127
  LabelKnob 2,{ }
  LabelKnob 3,{ }
@End