Pitchbend Wheel range in OB-Xd

VoytecG

Listen dear forumers, I have this issue; I would like to use OB-Xd in my live rig, but there is one problem; OB-Xd has only two pitchbend wheel settings; whole tone or full octawe. Is there any tool that would allow me to adjust the Pitchbend Wheel range so that I can use the normal range for me, which is 5 or 7 semitones? My host is AUM.
Cheers everybody.

uncledave

Hmmm. You could use the 1 octave range and use a script (StreamByter or Mozaic) to scale the range down to what you want. It's a bit "mathy" due to various MIDI annoyances, but I could do it. Basically, when you send maximum value from the wheel, you want to convert that to 5/12 of maximum for the app.

uncledave

So here's my StreamByter script. This ought to work for you.
Edit: Corrected minimum settings, and maximum limit to prevent errors.
Edit: Another minor fix!

#BendRange
# StreamByter script to scale pitch bend down.

# Load StreamByter in a MIDI slot. Paste this in and
# Install Rules. You can Save it for later reuse (hamburger
# menu in lower right). Adjust the ranges for the synth app
# and for your desired maximum (must be smaller).
# Route MIDI from your controller, through StreamByter,
# and on to the synth. All MIDI will be passed on; only
# pitch bend will be affected. The displayed values at the
# bottom show the signed input bend value and the scaled
# output. Tap the magnifier to see the actual input and
# output messages. Tap the "globe" icon in lower right to
# switch between controls and edit screen.

If load
# Screen Controllers ———————————————————————————
Alias Q0 theSynthRange
Alias Q1 theTargetRange
Set Q0 Synth_Range 2 $24
Set Q1 Target_Range 1 $24
Set Q2 +H
Set Q3 +H

Set Q4 +H
Set Q5 +H
Set Q6 +H
Set Q7 +H

Ass Q0 = $12 $5 0 0  0 0 0 0  +P

Mat K00 = theSynthRange / 2
Set Sliderdisplay 1
# End Screen Controllers —————————————————————————

# M1 and M2 are the bend value LSB and MSB in the MIDI message
Sub ScaleBend
   Mat P0 = 80 * M2      # assemble 14-bit value
   Mat P0 = P0 + M1
   Mat P0 = P0 - 2000      # P0 is signed, so this works
   Set LB0 P0 +D      # display original signed value
   ass I10 = 0
   if P0 < 0
      mat P0 = 0 - P0
      ass I10 = 1
   end
   Mat P0 = P0 * theTargetRange
   mat P0 = P0 + K00      # this enables rounding
   Mat P0 = P0 / theSynthRange      # scale it down
   If P0 > 1FFF
      Ass P0 = 1FFF
   End
   if I10 == 1
      mat P0 = 0 - P0
   end
   Set LB1 P0 +D      # display scaled signed value
   Mat P0 = P0 + 2000      # convert back to LSB, MSB
   Mat M1 = P0 & 7F
   Mat M2 = P0 / 80
End

Set Name Bendr
End # Initialization ———————————————————————————

If MT == E0
   ScaleBend
End 

If M0 == F0 7D 01       # handle system events
   Mat K00 = theSynthRange / 2
End

VoytecG

@uncledave, thank you very much!
I'll launch it in the evening.

uncledave

@VoytecG said:
@uncledave, thank you very much!
I'll launch it in the evening.

Hi. I made a couple of small changes, so you should copy the script again. They only affect extreme cases, but better to be safe.
Cheers!

VoytecG

@uncledave said:

@VoytecG said:
@uncledave, thank you very much!
I'll launch it in the evening.

Hi. I made a couple of small changes, so you should copy the script again. They only affect extreme cases, but better to be safe.
Cheers!

@uncledave is great!
Everything works like a charm!

uncledave

@VoytecG said:

@uncledave said:

@VoytecG said:
@uncledave, thank you very much!
I'll launch it in the evening.

Hi. I made a couple of small changes, so you should copy the script again. They only affect extreme cases, but better to be safe.
Cheers!

@uncledave is great!
Everything works like a charm!

Good. I've made one small additional change (7F not 3F near end of ScaleBend subroutine). Only affects the least significant byte, so hardly detectable, but was wrong.