Mozaic Footswitch Plus Keyboard Note to send PC and Session load in AUM.

Bellows

Hi Friends
If I am posting this to the wrong area please spin me around and head me the right way😎
I have returned after a long time gone. Mozaic is a great tool.
I am trying to use make my setup very small and portable. I want to use only one switch on my Airturn Bluetooth pedal combined with one midi note from my keyboard to make PC and/or Session load in AUM.
The plan is whenever I want to send such a message I will hold down the footswitch sending a CC VALUE of 127 to AUM. This value will be added to a note number selected on my keyboard (a small Roland V-Accordion🪗). The result will select a PC or Session Load in AUM.
I have written some script and the footswitch portion works well. I have also triggered PCs and Session loads in AUM properly.I don’t know a good way to add the values together to select which PC# gets sent. This is my obstacle at the moment.
BTW, the message to AUM cab be CC, PC, or Note#.
I don’t remember how you post code here properly.
Any help appreciated.
Bruce

espiegel123

@Bellows : what do you mean by “I will hold down the footswitch sending a CC VALUE of 127 to AUM. This value will be added to a note number selected on my keyboard”

Midi values (for anything other than pitchbend) are limited to 0 to 127. So you can’t add 127 to a midi value.

Can you describe differently what you want? Do you want the next note number after the pedal is pressed to be sent as a PC value?

wim

@Bellows - It sounds as though you want to pass notes from your V-Accordion through except for when you're holding down the foot switch. When the switch is held down you want the notes to be passed through as a PC message.

Is that correct?

Bellows

Thanks for the fast response. Good point about the 127 value. I was sending on/off CC # info and just picked 0 for off and 127 for on. I see the problem with that and will use 1 to represent “on”.
I have not explained my intention well enough.
When I press the footswitch I will change into a mode that will send a signal that will initiate a program change or a session load based on a key that is pressed on my keyboard.
I see from talking to you that the addition will not be necessary.
The switch activates the process and only then the keyboard will send out the note number information to select a new program or session.
When the footswitch is released the keyboard will resume its normal function.
Another way to think of it is that the footswitch redirects a note from the keyboard to effect a program change. The different keys on the keyboard will each select a different program..

The idea is I will be playing normally. Then stop playing momentarily, push the footswitch, press a keyboard key effecting a program change, release the footswitch and continue playing normally with a different program or session.

I hope this explains my plan. You have already helped immensely. Any other thoughts will be appreciated also.

espiegel123

@Bellows : that’s simple.

Create a variable called something like pcMode

Set it to 0 on load.

If your on message gets sent, set pcMode to 1. If off comes in set pcMode to 0

If a note on comes in, check to see if pcMode is 1. If it is, send a PC message out with whatever number is convenient. It could be the note number or calculated from the note number.

If pcMode is 0, send out a copy of the note message you received.

wim

It sounds as if my guess at what is wanted is correct. Here's a basic script I wrote while you two were discussing:

@Description
When foot switch is pressed, convert note On messages to Program Change. Otherwise, pass all midi through.
Configure the foot switch message in @OnLoad
Release the PC note before the foot switch to avoid extra Note-Off messages.
@End

@OnLoad
  // set the incoming cc, channel, and velocity from the footswitch
  cc = 20
  chan = 0
  velocity = 127
  passThru = YES
@End

@OnMidiCC
  if (MIDIChannel = chan) and (MIDIByte2 = cc)
    if MIDIByte3 = velocity
      passThru = NO
    else
      passThru = YES
    endif
  endif
@End

@OnMidiNote
  if not passThru
    if MIDICommand = 0x90   //Note ON only
      SendMIDIProgramChange chan,MIDINote
    endif
  else
    SendMIDIThru
  endif
@End

@OnMidiInput
// pass through midi messages not handled above
// 0x90 = Note ON, 0x80 = Note OFF, 0xB0 = CC
  if MIDICommand <> 0x90 and MIDICommand <> 0x80 and MIDICommand <> 0xB0
    SendMIDIThru
  endif
@End

@OnSysex
  SendSysexThru
@End

Bellows

Many thanks to both of you for your help.
Wim, your script works perfectly and I can understand it🤔😀
I will have a couple of more questions in the future but right now I am having a great time playing with it.
Thanks,
Bellows

wim

👍🏼

It was actually a really great idea for getting the most out of such a controller.

Bellows

@wim said:
👍🏼

It was actually a really great idea for getting the most out of such a controller.

Thanks Wim, I saw it years ago in an accompaniment program called Live Styler.
In Live Styler you sacrificed a key on the keyboard (usually the lowest least used key). When you held that key down with your thumb you could send a PC by adding another note with your fingers. There were also other functions performed by your fingers only when the lowest key was held down.
I did not do that here because my keyboard is already only two octaves as many controllers are today.
Thanks so much for your help.🪗🎶

Bellows

Hi Wim, just wanted to let you know how very well this script is working with AUM. It is soooo good.
I am using the first octave of my keyboard to initiate sessions.
I am using the second octave to call presets after the session is active.
Thank you so much for your help.
LooseBruce

wim

Hi @belllows - that's great to know.
I may polish it up a bit and post it on Patchstorage in case someone else can get use out of it.